Relay Chan1 & Chan2 to Chan3 on 1 eggdrop & 1 server

[mvp1]

Hi Guys,

I am after something very simple. I have an eggdrop on one server, e.g Dalnet, and I want it to join 3 channels, e.g #Chan1 , #Chan2 and #Chan3

And I want it to relay everything (chat,joins/parts etc etc) from #Chan1 and #Chan2 into #Chan3

Is there anything already available? Of if anyone can help with a simple TCL code please?

Many thanks in advance.

[CrazyCat]

Here is a simple script (untested) for relaying pub, join and part, feel free to add others (kicks, quits, act, ...):

Code: Select all

namespace eval spy {
   variable src {"#chan1" "#chan2"}
   variable dest "#chan3"

   bind pubm - * ::spy::spub
   proc spub {nick uhost handle chan text} {
      if {[lsearch -nocase $::spy::src $chan]==-1} { return }
      putserv "PRIVMSG $::spy::dest :${nick}${chan}> $text"
   }

   bind join - * ::spy::sjoin
   proc sjoin {nick uhost handle chan} {
      if {[lsearch -nocase $::spy::src $chan]==-1} { return }
      putserv "PRIVMSG $::spy::dest :--> $nick joined $chan"
   }

   bind part - * ::spy::spart
   proc spart {nick uhost handle chan reason} {
      if {[lsearch -nocase $::spy::src $chan]==-1} { return }
      putserv "PRIVMSG $::spy::dest :<-- $nick leaved $chan ($reason)"
   }
}

[mabrook]

This is working 99%, tested.

[mabrook]

@CrazyCat

can you please add on/off for the script.


chanset #channel -spy
chanset #channel +spy



thank you.

[CrazyCat]

This changes a little bit the way the script will work:

Code: Select all

namespace eval spy {

   setudef flag spy
   variable dest "#chan3"

   bind pubm - * ::spy::spub
   proc spub {nick uhost handle chan text} {
      if {![channel get $chan spy]} { return }
      putserv "PRIVMSG $::spy::dest :${nick}${chan}> $text"
   }

   bind join - * ::spy::sjoin
   proc sjoin {nick uhost handle chan} {
      if {![channel get $chan spy]} { return }
      putserv "PRIVMSG $::spy::dest :--> $nick joined $chan"
   }

   bind part - * ::spy::spart
   proc spart {nick uhost handle chan reason} {
      if {![channel get $chan spy]} { return }
      putserv "PRIVMSG $::spy::dest :<-- $nick leaved $chan ($reason)"
   }
}

Now, you can activate the spy on any channel you want, and deactivate it.

Think to never do a .chanset #chan3 +spy (when #chan3 is the destination channel)

[mabrook]

thank you.. it is working ..