Using a proc in a regsub?

[CrazyCat]

Hello there,

I'm trying to do a small tcl who generate a random string based on a pattern, I want to replace a special char ("?") with a random other char. The trouble is that this special char could be several times in the pattern, I don't want to have the same replacement.

I'm trying with someting like:

Code: Select all

proc rnd:replace {pattern} {
   regsub -all -- \? $pattern [rand 9] pattern
   return pattern
}

And sure, it fails (couldn't compile regular expression pattern: quantifier operand invalid)...
Is there a way to eval a proc in a regsub?

Thanks by advance

[user]

I think you mean "\\?", not "\?". The first backslash is substituted when the regsub line is evaluated, resulting in "?" being passed as a pattern to regsub, which will interpret the unescaped "?" as a quantifier - leading to the error message you got.

There is no way to invoke a command for each match using regsub - currently - some people in #tcl@freenode are experimenting with a new regexp engine that may be included in a future version of Tcl, but don't hold your breath

However... replacing a single character is easy to do using split,foreach and append:

Code: Select all

proc replacething {str find code} {
	set out ""
	foreach chr [split $str ""] {
		append out [if {[string eq $chr $find]} {eval $code} {set chr}]
	}
	set out
}

# tclsh tests:
% proc rand i {expr {int(rand()*$i)}};# there's no [rand] in tclsh
% replacething "Hello????" ? {rand 9}
Hello5643
% replacething "axaxax" x {format %c [expr {65+int(rand()*26)}]}
aZaWaU

[CrazyCat]

OK, that's what I was thinking...
I'm used to use regexp in PHP, with callback function and eval...

Thanks a lot