Async socket waits untill ends

[Ofloo]

Code: Select all

#!/usr/bin/tclsh

proc open_sock {host port} {
   global done
   if {[catch {socket -async $host $port} sock]} {
      puts "Connection to $host:$port failed: $sock"
   } else {
      fileevent $sock writable [list check_sock $sock $host $port]
      vwait done($sock)
   }
}
proc check_sock {sock host port} {
   global done
   if {[fconfigure $sock -error]==""} {
      puts "Connected to $host:$port"
   } else {
      puts "Connection to $host:$port failed: [fconfigure $sock -error]"
   }
   close $sock
   set done($sock) 1
}

i am using an async socket in a while to connect to multiple targets at once but there appears to be no difference when i use a async socket or a regular one.. it waits untill the proc has ended .. why is this ?

i am using foreach ... to go true the process any suggestions to speed it up?

[caesar]

Probably cos of the 'vwait done($sock)'

[Ofloo]

well its required in a shell script otherwize the app would close ..

[stdragon]

Eggdrop won't exit when your script ends, so you don't need the vwait.

[user]

Move the vwait to after your while loop? (remove it from the proc)

Eggdrop won't exit when your script ends, so you don't need the vwait.

I don't think he's running it in eggdrop's interpreter:

Code: Select all

#!/usr/bin/tclsh

[Ofloo]

where exactly cause ive tryed it and i got would wait forever and script breaks

[Ofloo]

and yes sorry hehe by shell i meanth shell script as in tclsh not as in eggdrop shell..

[user]

where exactly cause ive tryed it and i got would wait forever and script breaks

Try this:

Code: Select all

proc open_sock {host port} { 
	if {[catch {socket -async $host $port} sock]} {
		puts "Connection to $host:$port failed: $sock"
		return 0
	} else {
		fileevent $sock writable [list check_sock $sock $host $port] 
		return 1
	}
} 
proc check_sock {sock host port} { 
	global pending
	if {[fconfigure $sock -error]==""} { 
		puts "Connected to $host:$port" 
	} else { 
		puts "Connection to $host:$port failed: [fconfigure $sock -error]" 
	} 
	close $sock
	incr pending -1;
}

proc doit args {
	global pending
	set pending 0
	foreach {host port} $args {
		incr pending [open_sock $host $port]
	}
	while {$pending} {vwait pending}
	puts done.
}

doit localhost 22 localhost 23 localhost 25 localhost 110